for-in для DB-запросов

Наконец появилась мысль для написания статьи. В общем-то заметка будет скорее относиться к разряду прикладных "tricks&tips". Достаточно часто в работе возникает необходимость весьма не хитрым способом обрабатывать результаты работы SQL запросов, и обычно эта процедура выглядит так:

q := TAdoQuery.Create(nil);
q.SQL.text := '..';
try
    q.Open();
    while not q.eof do begin
        writeln(q.fieldByName('id').AsInteger);
        q.Next();
    end;
finalyy
    q.Free();
end;

Сейчас в связи с производственной необходимостью читаю книги по C#, .NET & MVC, и они там так ловко обращаются с результатами запросов, что появилась мысль, почему бы и нам несколько не упростить эту конструкцию.  И под фразой "упростить" подразумевается замена конструкции "while not eof do ... next" на "for row in query", что будет по сути делать то же самое, но избавлять нас от частых фраз вида "епт, опять next забыл" с уходом в бесконечный цикл.

Собственно, как вы понимаете процедура перехода к такому циклу весьма проста. И нам всего лишь необходимо расширить класс реализующий запрос методом GetEnumerator, либо (что было бы более эффективно в нашем случае), расширить интерфейсом IEnumerable. Но для примера выберем простой вариант.

Класс мы расширим без использования наследования - за счет классов помощников, поскольку в данном случае нам не потребуется иных модификаций исходного кода. Итак, на примере TADOQuery нам понадобится следующее класс помощник, класс перечислителя, и класс для текущей записи. Напишем класс помощник:

interface
uses ADODB, DB;

type
    TRow = class;
    TRowEnumerator = class;

    TADOQueryHelper = class helper for TADOQuery
        function getEnumerator():TRowEnumerator;
    end;


.....


function TADOQueryHelper.getEnumerator(): TRowEnumerator;
begin
    result := TRowEnumerator.Create(self);
end;

Естественно, чтобы перечислителю было с чем работать, то передаем ему ссылку на сам запрос с которым работать в качестве параметра конструктора. Далее сам перечислитель, где нам нужно реализовать всего два метода - MoveNext, возвращающий булевый результат, и свойство Current.

    TRowEnumerator = class(TObject)
      strict private
        FQuery : TADOQuery;
        FFirstTime : boolean;
        FRow : TRow;
      public
        constructor Create(q : TADOQuery);
        destructor Destroy(); override;

        function MoveNext():boolean;
        property Current : TRow read FRow;
    end;

Текущий элемент будет представлен классом TRow, реализация которого позволяет много фантазировать, но для примера, мне нужен только функционал получения доступа к полям текущей строки запроса:

    TRow = class(TObject)
      private
        FQuery : TADOQuery;
        constructor Create(q : TADOQuery);
      public
        function FieldByName(aField : string) : TField;
    end;

.....

constructor TRow.Create(q: TADOQuery);
begin
    inherited Create();
    FQuery := q;
end;

function TRow.FieldByName(aField: string): TField;
begin
    result := FQuery.FieldByName(aField);
end;

Реализация перечислителя, конечно, тоже весьма очевидна. Но есть один нюанс на который необходимо обратить внимание: при первом вызове MoveNext нам не требуется вызывать Next у запроса, поскольку в этом случае мы пропустим первую строку результатов. Поскольку экземпляр TRow всегда будет  работать непосредственно с запросом, то создаваться он будет только один раз в конструкторе.

constructor TRowEnumerator.Create(q: TADOQuery);
begin
    inherited Create();
    FQuery := q;
    FRow := TRow.Create(FQuery);

    FFirstTime := true;
end;

destructor TRowEnumerator.Destroy();
begin
    FRow.Free();
    inherited;
end;

function TRowEnumerator.MoveNext(): boolean;
begin
    if not FFirstTime then
        FQuery.Next()
    else FFirstTime := false;

    result := not FQuery.Eof;
end;

Вот собственно и все. В результате применения данного кода мы сможем использовать конструкции следующего вида, что может и пригодиться порой:

        q.SQL.Text := 'SELECT TOP 10 id, name_eng FROM subjects ORDER BY id';

        q.Open();
        try
            for row in q do begin
                writeln(row.FieldByName('id').AsInteger, ' - ',
                        row.FieldByName('name_eng').AsString);
            end;
        finally
            q.Close();
        end;