Цепочки событий (Event Chain) RTTI#8

Я писал следующий модуль когда требовалось узнавать о изменениях на форме:

{
   Модуль содержит класс, контролирующий изменения в основных
   компонентах VCL и сигнализирующий об этом.

   Принцип работы: На вход подается компонент (форма, или панель) на котором
   требуется узнать об изменениях. Класс пробегает по всем контролам
   на указанном компоненте, и назначает свой обработчик событиям.
}

unit sbChangeHandlerUnit;

interface

uses
  Classes, SysUtils, Forms, StdCtrls, ComCtrls, ExtCtrls, Spin;

type
  TsbNotifyChangeEvent = procedure(Component: TObject) of object;

  TsbChangeHandler = class
  private
    //1 Список компонентов с переопределенным обработчиком OnChange
    FControls: TList;
    //1 Список оригинальных обработчиков
    FMetodCodes: TList;
    FMethodData: TList;
    FOnChange: TsbNotifyChangeEvent;

    procedure DoOnChange(Component: TObject);

    procedure StoreHandler(Control: TObject; Handler: TMethod);
    procedure SettingsChange(Sender: TObject);
    procedure SettingsChange2(Sender: TObject; Item: TListItem; Change: TItemChange);
    procedure SetHook(Component: TObject; OriginalRuotine: TMethod);
  public
    constructor Create;
    destructor Destroy; override;
    procedure StartMonitorFor(Control: TComponent);

    property OnChange: TsbNotifyChangeEvent read FOnChange write FOnChange;
  end;

implementation

{ TsbChangeHandler }

constructor TsbChangeHandler.Create;
begin
  inherited Create;

  FControls := TList.Create;
  FMetodCodes := TList.Create;
  FMethodData := TList.Create;
end;

destructor TsbChangeHandler.Destroy;
begin
  FreeAndNil(FControls);
  FreeAndNil(FMetodCodes);
  FreeAndNil(FMethodData);

  inherited Destroy;
end;

procedure TsbChangeHandler.DoOnChange(Component: TObject);
begin
  if Assigned(FOnChange) then
    FOnChange(Component);
end;

procedure TsbChangeHandler.StoreHandler(Control: TObject; Handler: TMethod);
begin
  FControls.Add(Control);
  FMetodCodes.Add(Handler.Code);
  FMethodData.Add(Handler.Data);
end;

procedure TsbChangeHandler.SetHook(Component: TObject; OriginalRuotine: TMethod);
begin
  if Assigned(OriginalRuotine.Code) then
    StoreHandler(Component, OriginalRuotine);
end;

procedure TsbChangeHandler.SettingsChange(Sender: TObject);
var
  Idx: Integer;
  Method: TMethod;
begin
  Idx := FControls.IndexOf(Sender);
  if Idx > -1 then
  begin
    Method.Code := FMetodCodes[Idx];
    Method.Data := FMethodData[Idx];
    TNotifyEvent(Method)(Sender);
  end;

  DoOnChange(Sender);
end;

procedure TsbChangeHandler.SettingsChange2(Sender: TObject; Item: TListItem; Change: TItemChange);
var
  Idx: Integer;
  Method: TMethod;
begin
  Idx := FControls.IndexOf(Sender);
  if Idx > -1 then
  begin
    Method.Code := FMetodCodes[Idx];
    Method.Data := FMethodData[Idx];
    TLVChangeEvent(Method)(Sender, Item, Change);
  end;

  DoOnChange(Sender);
end;

procedure TsbChangeHandler.StartMonitorFor(Control: TComponent);
var
  Loop: Integer;
begin
  with Control do
    //Проходим по все контролам элемента за изменением которого устанавливается наблюдение
    for Loop := 0 to ComponentCount - 1 do
    begin
      //Если компонент имеет дочернии компоненты (например форма), то рекурсивно начинаем следить и за ними
      if Components[Loop].ComponentCount > 0 then
        StartMonitorFor(Components[Loop]);

      if Components[Loop] is TCheckBox then
      begin
        SetHook(Components[Loop], TMethod(TCheckBox(Components[Loop]).OnClick));
        TCheckBox(Components[Loop]).OnClick := SettingsChange;
      end;

      if Components[Loop] is TEdit then
      begin
        SetHook(Components[Loop], TMethod(TEdit(Components[Loop]).OnChange));
        TEdit(Components[Loop]).OnChange := SettingsChange;
      end;

      if Components[Loop] is TLabeledEdit then
      begin
        SetHook(Components[Loop], TMethod(TLabeledEdit(Components[Loop]).OnChange));
        TLabeledEdit(Components[Loop]).OnChange := SettingsChange;
      end;

      if Components[Loop] is TComboBox then
      begin
        SetHook(Components[Loop], TMethod(TComboBox(Components[Loop]).OnChange));
        TComboBox(Components[Loop]).OnChange := SettingsChange;
      end;

      if Components[Loop] is TMemo then
      begin
        SetHook(Components[Loop], TMethod(TMemo(Components[Loop]).OnChange));
        TMemo(Components[Loop]).OnChange := SettingsChange;
      end;

      if Components[Loop] is TRadioGroup then
      begin
        SetHook(Components[Loop], TMethod(TSpinEdit(Components[Loop]).OnClick));
        TSpinEdit(Components[Loop]).OnClick := SettingsChange;
      end;

      if Components[Loop] is TSpinEdit then
      begin
        SetHook(Components[Loop], TMethod(TSpinEdit(Components[Loop]).OnChange));
        TSpinEdit(Components[Loop]).OnChange := SettingsChange;
      end;

      if Components[Loop] is TTrackBar then
      begin
        SetHook(Components[Loop], TMethod(TTrackBar(Components[Loop]).OnChange));
        TTrackBar(Components[Loop]).OnChange := SettingsChange;
      end;

      if Components[Loop] is TListView then
      begin
        SetHook(Components[Loop], TMethod(TListView(Components[Loop]).OnChange));
        TListView(Components[Loop]).OnChange := SettingsChange2;
      end;

      if Components[Loop] is TRadioButton then
      begin
        SetHook(Components[Loop], TMethod(TRadioButton(Components[Loop]).OnClick));
        TRadioButton(Components[Loop]).OnClick := SettingsChange;
      end;
    end;
end;

end.