WMI & process list

WMI может быть использован не только для получения статистической информации, как в предыдущем примере, но и , например, для мониторинга системных ресурсов, для чего предусмотрены классы Win32_PerfRawData & Win32_PerfFormattedData. Рассмотрим пример мониторинга списка процессов Windows. Данная задача достаточно проста в реализации с использованием WMI и сводится к десятку-другому строк кода. Для мониторинга и обновления данных объектов/классов унаследованных от Win32_Perf...Data требуется использовать объект класса ISWbemRefresher, который хранит коллекцию объектов для обновления. Для отображения информации на форму добавим processListView : TListView, и обновлять данные будем по событию таймера. При создании формы создадим объект для обновления, и сохраним его в private секции. При добавлении класса в коллекцию ISWbemRefresher возвращает экземпляр ISWbemRefresherItem, из которого мы уже и будем извлекать обновленные данные. Расширим программу предыдущего примера следующим образом:

  private
     refresher : ISWbemRefresher;
     refresherItem : ISWbemRefreshableItem;

..
procedure TMainForm.FormCreate(Sender: TObject);
...
    refresher := CoSWbemRefresher.Create;
    refresherItem := refresher.AddEnum(services as ISWbemServicesEx,'Win32_PerfFormattedData_PerfProc_Process',0,nil);
    timer.Enabled := true;
end;

Ок. теперь refresherItem будет содержать список наших процессов, и мы можем его обновлять по событию таймера, и непосредственно выводить в список processListView.

procedure TMainForm.TimerTimer(Sender: TObject);
var
    pObject    : ISWbemObject;
    pCount : cardinal;
    i:cardinal;
begin
    Refresher.Refresh(0);
    pCount :=     refresherItem.ObjectSet.Count - 1;
    processListView.Items.BeginUpdate;
    processListView.Items.Clear;
    for i:=0 to pCount do begin
       pObject :=     refresherItem.ObjectSet.ItemIndex(i);
       AddProcessToList(pObject);
    end;
    processListView.Items.EndUpdate;
end;

Собственно добавление информации о процессе в производится функция AddProcessToList():

procedure TMainForm.AddProcessToList(var pObject: ISWbemObject);
var name : string;
    pid  : cardinal;
    usage: cardinal;
    pItem : TListItem;
begin
    name := pObject.Properties_.Item('Name',0).Get_Value;
    pid  := pObject.Properties_.Item('IdProcess',0).get_Value;
    usage:= pObject.Properties_.Item('PercentProcessorTime',0).get_Value;

    pItem := processListView.Items.Add();
    pItem.Caption := name;
    pItem.SubItems.Add(intToStr(pid));
    pItem.SubItems.Add(intToStr(usage));
end;

вот собственно и все. к минусам данного решения можно отнести то, что информация о загрузке процессора приводится в целых числах, что в принципе можно изменить, используя вместо класса Win32_PerfFormattedData класс Win32_PerfRawData, в котором данные о загрузке процессора придется рассчитать самому. Ну и во вторых я так и не понял почему idle процесс всегда 100% показывает :) ах да. в третьих еще то, что имена процессов приводятся в не совсем привычном виде, но имея PID процесса можно получить его handle, и потом уже и имя исполняемого файла.